innosetup: Add i2pd to PATH

Win32/inno_installer.iss

@@ -25,6 +25,10 @@ Source: "..\README.md"; DestDir: "{app}"; DestName: "Readme.txt"; AfterInstall:
 Name: "{group}\I2Pd"; Filename: "{app}\i2pd.exe"
 Name: "{group}\Readme"; Filename: "{app}\Readme.txt"
 
+
+[Registry]
+Root: HKCU; Subkey: "Environment"; ValueName: "Path"; ValueType: "string"; ValueData: "{app};{olddata}"; Check: NotOnPathAlready(); Flags: preservestringtype;
+
 [Code]
 
 var
@@ -98,3 +102,48 @@ begin
     WizardForm.Bevel.Top := DefaultBevelTop;
   end;
 end;
+
+function NotOnPathAlready(): Boolean;
+var
+  BinDir, Path: String;
+begin
+  Log('Checking if i2pd dir is already in the %PATH%');
+  if RegQueryStringValue(HKEY_CURRENT_USER, 'Environment', 'Path', Path) then
+  begin // Successfully read the value
+    Log('HKCUEnvironmentPATH = ' + Path);
+    BinDir := ExpandConstant('{app}');
+    Log('Looking for i2pd dir in %PATH%: ' + BinDir + ' in ' + Path);
+    if Pos(LowerCase(BinDir), Lowercase(Path)) = 0 then
+    begin
+      Log('Did not find i2pd dir in %PATH% so I will add it');
+      Result := True;
+    end
+    else
+    begin
+      Log('Found i2pd dir in %PATH% so will not add it again');
+      Result := False;
+    end
+  end
+  else // The key probably doesn't exist
+  begin
+    Log('Could not access HKCUEnvironmentPATH so I assume that it is OK to add it');
+    Result := True;
+  end;
+end;
+
+
+procedure CurUninstallStepChanged(CurUninstallStep: TUninstallStep);
+var
+  BinDir, Path: String;
+begin
+  if (CurUninstallStep = usPostUninstall)
+     and (RegQueryStringValue(HKEY_CURRENT_USER, 'Environment', 'PATH', Path)) then
+  begin
+    BinDir := ExpandConstant('{app}');
+    if Pos(LowerCase(BinDir) + ';', Lowercase(Path)) <> 0 then
+    begin
+      StringChange(Path, BinDir + ';', '');
+      RegWriteStringValue(HKEY_CURRENT_USER, 'Environment', 'PATH', Path);
+    end;
+  end;
+end;