mirror of https://github.com/GOSTSec/ccminer
You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
662 lines
19 KiB
662 lines
19 KiB
/** |
|
* Lyra2 (v1) cuda implementation based on djm34 work |
|
* tpruvot@github 2015, Nanashi 08/2016 (from 1.8-r2) |
|
* tpruvot@github 2018 for phi2 double lyra2-32 support |
|
*/ |
|
|
|
#include <stdio.h> |
|
#include <memory.h> |
|
|
|
#define TPB52 32 |
|
|
|
#include "cuda_lyra2_sm2.cuh" |
|
#include "cuda_lyra2_sm5.cuh" |
|
|
|
#ifdef __INTELLISENSE__ |
|
/* just for vstudio code colors */ |
|
#define __CUDA_ARCH__ 520 |
|
#endif |
|
|
|
#if !defined(__CUDA_ARCH__) || __CUDA_ARCH__ > 500 |
|
|
|
#include "cuda_lyra2_vectors.h" |
|
|
|
#ifdef __INTELLISENSE__ |
|
/* just for vstudio code colors */ |
|
__device__ uint32_t __shfl(uint32_t a, uint32_t b, uint32_t c); |
|
#endif |
|
|
|
#define Nrow 8 |
|
#define Ncol 8 |
|
#define memshift 3 |
|
|
|
#define BUF_COUNT 0 |
|
|
|
__device__ uint2 *DMatrix; |
|
|
|
__device__ __forceinline__ void LD4S(uint2 res[3], const int row, const int col, const int thread, const int threads) |
|
{ |
|
#if BUF_COUNT != 8 |
|
extern __shared__ uint2 shared_mem[]; |
|
const int s0 = (Ncol * (row - BUF_COUNT) + col) * memshift; |
|
#endif |
|
#if BUF_COUNT != 0 |
|
const int d0 = (memshift *(Ncol * row + col) * threads + thread)*blockDim.x + threadIdx.x; |
|
#endif |
|
|
|
#if BUF_COUNT == 8 |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
res[j] = *(DMatrix + d0 + j * threads * blockDim.x); |
|
#elif BUF_COUNT == 0 |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
res[j] = shared_mem[((s0 + j) * blockDim.y + threadIdx.y) * blockDim.x + threadIdx.x]; |
|
#else |
|
if (row < BUF_COUNT) |
|
{ |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
res[j] = *(DMatrix + d0 + j * threads * blockDim.x); |
|
} |
|
else |
|
{ |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
res[j] = shared_mem[((s0 + j) * blockDim.y + threadIdx.y) * blockDim.x + threadIdx.x]; |
|
} |
|
#endif |
|
} |
|
|
|
__device__ __forceinline__ void ST4S(const int row, const int col, const uint2 data[3], const int thread, const int threads) |
|
{ |
|
#if BUF_COUNT != 8 |
|
extern __shared__ uint2 shared_mem[]; |
|
const int s0 = (Ncol * (row - BUF_COUNT) + col) * memshift; |
|
#endif |
|
#if BUF_COUNT != 0 |
|
const int d0 = (memshift *(Ncol * row + col) * threads + thread)*blockDim.x + threadIdx.x; |
|
#endif |
|
|
|
#if BUF_COUNT == 8 |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
*(DMatrix + d0 + j * threads * blockDim.x) = data[j]; |
|
|
|
#elif BUF_COUNT == 0 |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
shared_mem[((s0 + j) * blockDim.y + threadIdx.y) * blockDim.x + threadIdx.x] = data[j]; |
|
|
|
#else |
|
if (row < BUF_COUNT) |
|
{ |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
*(DMatrix + d0 + j * threads * blockDim.x) = data[j]; |
|
} |
|
else |
|
{ |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
shared_mem[((s0 + j) * blockDim.y + threadIdx.y) * blockDim.x + threadIdx.x] = data[j]; |
|
} |
|
#endif |
|
} |
|
|
|
#if __CUDA_ARCH__ >= 300 |
|
__device__ __forceinline__ uint32_t WarpShuffle(uint32_t a, uint32_t b, uint32_t c) |
|
{ |
|
return __shfl(a, b, c); |
|
} |
|
|
|
__device__ __forceinline__ uint2 WarpShuffle(uint2 a, uint32_t b, uint32_t c) |
|
{ |
|
return make_uint2(__shfl(a.x, b, c), __shfl(a.y, b, c)); |
|
} |
|
|
|
__device__ __forceinline__ void WarpShuffle3(uint2 &a1, uint2 &a2, uint2 &a3, uint32_t b1, uint32_t b2, uint32_t b3, uint32_t c) |
|
{ |
|
a1 = WarpShuffle(a1, b1, c); |
|
a2 = WarpShuffle(a2, b2, c); |
|
a3 = WarpShuffle(a3, b3, c); |
|
} |
|
|
|
#else |
|
__device__ __forceinline__ uint32_t WarpShuffle(uint32_t a, uint32_t b, uint32_t c) |
|
{ |
|
extern __shared__ uint2 shared_mem[]; |
|
|
|
const uint32_t thread = blockDim.x * threadIdx.y + threadIdx.x; |
|
uint32_t *_ptr = (uint32_t*)shared_mem; |
|
|
|
__threadfence_block(); |
|
uint32_t buf = _ptr[thread]; |
|
|
|
_ptr[thread] = a; |
|
__threadfence_block(); |
|
uint32_t result = _ptr[(thread&~(c - 1)) + (b&(c - 1))]; |
|
|
|
__threadfence_block(); |
|
_ptr[thread] = buf; |
|
|
|
__threadfence_block(); |
|
return result; |
|
} |
|
|
|
__device__ __forceinline__ uint2 WarpShuffle(uint2 a, uint32_t b, uint32_t c) |
|
{ |
|
extern __shared__ uint2 shared_mem[]; |
|
|
|
const uint32_t thread = blockDim.x * threadIdx.y + threadIdx.x; |
|
|
|
__threadfence_block(); |
|
uint2 buf = shared_mem[thread]; |
|
|
|
shared_mem[thread] = a; |
|
__threadfence_block(); |
|
uint2 result = shared_mem[(thread&~(c - 1)) + (b&(c - 1))]; |
|
|
|
__threadfence_block(); |
|
shared_mem[thread] = buf; |
|
|
|
__threadfence_block(); |
|
return result; |
|
} |
|
|
|
__device__ __forceinline__ void WarpShuffle3(uint2 &a1, uint2 &a2, uint2 &a3, uint32_t b1, uint32_t b2, uint32_t b3, uint32_t c) |
|
{ |
|
extern __shared__ uint2 shared_mem[]; |
|
|
|
const uint32_t thread = blockDim.x * threadIdx.y + threadIdx.x; |
|
|
|
__threadfence_block(); |
|
uint2 buf = shared_mem[thread]; |
|
|
|
shared_mem[thread] = a1; |
|
__threadfence_block(); |
|
a1 = shared_mem[(thread&~(c - 1)) + (b1&(c - 1))]; |
|
__threadfence_block(); |
|
shared_mem[thread] = a2; |
|
__threadfence_block(); |
|
a2 = shared_mem[(thread&~(c - 1)) + (b2&(c - 1))]; |
|
__threadfence_block(); |
|
shared_mem[thread] = a3; |
|
__threadfence_block(); |
|
a3 = shared_mem[(thread&~(c - 1)) + (b3&(c - 1))]; |
|
|
|
__threadfence_block(); |
|
shared_mem[thread] = buf; |
|
__threadfence_block(); |
|
} |
|
|
|
#endif |
|
|
|
#if __CUDA_ARCH__ > 500 || !defined(__CUDA_ARCH) |
|
static __device__ __forceinline__ |
|
void Gfunc(uint2 &a, uint2 &b, uint2 &c, uint2 &d) |
|
{ |
|
a += b; uint2 tmp = d; d.y = a.x ^ tmp.x; d.x = a.y ^ tmp.y; |
|
c += d; b ^= c; b = ROR24(b); |
|
a += b; d ^= a; d = ROR16(d); |
|
c += d; b ^= c; b = ROR2(b, 63); |
|
} |
|
#endif |
|
|
|
__device__ __forceinline__ void round_lyra(uint2 s[4]) |
|
{ |
|
Gfunc(s[0], s[1], s[2], s[3]); |
|
WarpShuffle3(s[1], s[2], s[3], threadIdx.x + 1, threadIdx.x + 2, threadIdx.x + 3, 4); |
|
Gfunc(s[0], s[1], s[2], s[3]); |
|
WarpShuffle3(s[1], s[2], s[3], threadIdx.x + 3, threadIdx.x + 2, threadIdx.x + 1, 4); |
|
} |
|
|
|
static __device__ __forceinline__ |
|
void round_lyra(uint2x4* s) |
|
{ |
|
Gfunc(s[0].x, s[1].x, s[2].x, s[3].x); |
|
Gfunc(s[0].y, s[1].y, s[2].y, s[3].y); |
|
Gfunc(s[0].z, s[1].z, s[2].z, s[3].z); |
|
Gfunc(s[0].w, s[1].w, s[2].w, s[3].w); |
|
Gfunc(s[0].x, s[1].y, s[2].z, s[3].w); |
|
Gfunc(s[0].y, s[1].z, s[2].w, s[3].x); |
|
Gfunc(s[0].z, s[1].w, s[2].x, s[3].y); |
|
Gfunc(s[0].w, s[1].x, s[2].y, s[3].z); |
|
} |
|
|
|
static __device__ __forceinline__ |
|
void reduceDuplex(uint2 state[4], uint32_t thread, const uint32_t threads) |
|
{ |
|
uint2 state1[3]; |
|
|
|
#pragma unroll |
|
for (int i = 0; i < Nrow; i++) |
|
{ |
|
ST4S(0, Ncol - i - 1, state, thread, threads); |
|
|
|
round_lyra(state); |
|
} |
|
|
|
#pragma unroll 4 |
|
for (int i = 0; i < Nrow; i++) |
|
{ |
|
LD4S(state1, 0, i, thread, threads); |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= state1[j]; |
|
|
|
round_lyra(state); |
|
|
|
for (int j = 0; j < 3; j++) |
|
state1[j] ^= state[j]; |
|
ST4S(1, Ncol - i - 1, state1, thread, threads); |
|
} |
|
} |
|
|
|
static __device__ __forceinline__ |
|
void reduceDuplexRowSetup(const int rowIn, const int rowInOut, const int rowOut, uint2 state[4], uint32_t thread, const uint32_t threads) |
|
{ |
|
uint2 state1[3], state2[3]; |
|
|
|
#pragma unroll 1 |
|
for (int i = 0; i < Nrow; i++) |
|
{ |
|
LD4S(state1, rowIn, i, thread, threads); |
|
LD4S(state2, rowInOut, i, thread, threads); |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= state1[j] + state2[j]; |
|
|
|
round_lyra(state); |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state1[j] ^= state[j]; |
|
|
|
ST4S(rowOut, Ncol - i - 1, state1, thread, threads); |
|
|
|
// simultaneously receive data from preceding thread and send data to following thread |
|
uint2 Data0 = state[0]; |
|
uint2 Data1 = state[1]; |
|
uint2 Data2 = state[2]; |
|
WarpShuffle3(Data0, Data1, Data2, threadIdx.x - 1, threadIdx.x - 1, threadIdx.x - 1, 4); |
|
|
|
if (threadIdx.x == 0) |
|
{ |
|
state2[0] ^= Data2; |
|
state2[1] ^= Data0; |
|
state2[2] ^= Data1; |
|
} else { |
|
state2[0] ^= Data0; |
|
state2[1] ^= Data1; |
|
state2[2] ^= Data2; |
|
} |
|
|
|
ST4S(rowInOut, i, state2, thread, threads); |
|
} |
|
} |
|
|
|
static __device__ __forceinline__ |
|
void reduceDuplexRowt(const int rowIn, const int rowInOut, const int rowOut, uint2 state[4], const uint32_t thread, const uint32_t threads) |
|
{ |
|
for (int i = 0; i < Nrow; i++) |
|
{ |
|
uint2 state1[3], state2[3]; |
|
|
|
LD4S(state1, rowIn, i, thread, threads); |
|
LD4S(state2, rowInOut, i, thread, threads); |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= state1[j] + state2[j]; |
|
|
|
round_lyra(state); |
|
|
|
// simultaneously receive data from preceding thread and send data to following thread |
|
uint2 Data0 = state[0]; |
|
uint2 Data1 = state[1]; |
|
uint2 Data2 = state[2]; |
|
WarpShuffle3(Data0, Data1, Data2, threadIdx.x - 1, threadIdx.x - 1, threadIdx.x - 1, 4); |
|
|
|
if (threadIdx.x == 0) |
|
{ |
|
state2[0] ^= Data2; |
|
state2[1] ^= Data0; |
|
state2[2] ^= Data1; |
|
} |
|
else |
|
{ |
|
state2[0] ^= Data0; |
|
state2[1] ^= Data1; |
|
state2[2] ^= Data2; |
|
} |
|
|
|
ST4S(rowInOut, i, state2, thread, threads); |
|
|
|
LD4S(state1, rowOut, i, thread, threads); |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state1[j] ^= state[j]; |
|
|
|
ST4S(rowOut, i, state1, thread, threads); |
|
} |
|
} |
|
|
|
static __device__ __forceinline__ |
|
void reduceDuplexRowt_8(const int rowInOut, uint2* state, const uint32_t thread, const uint32_t threads) |
|
{ |
|
uint2 state1[3], state2[3], last[3]; |
|
|
|
LD4S(state1, 2, 0, thread, threads); |
|
LD4S(last, rowInOut, 0, thread, threads); |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= state1[j] + last[j]; |
|
|
|
round_lyra(state); |
|
|
|
// simultaneously receive data from preceding thread and send data to following thread |
|
uint2 Data0 = state[0]; |
|
uint2 Data1 = state[1]; |
|
uint2 Data2 = state[2]; |
|
WarpShuffle3(Data0, Data1, Data2, threadIdx.x - 1, threadIdx.x - 1, threadIdx.x - 1, 4); |
|
|
|
if (threadIdx.x == 0) |
|
{ |
|
last[0] ^= Data2; |
|
last[1] ^= Data0; |
|
last[2] ^= Data1; |
|
} else { |
|
last[0] ^= Data0; |
|
last[1] ^= Data1; |
|
last[2] ^= Data2; |
|
} |
|
|
|
if (rowInOut == 5) |
|
{ |
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
last[j] ^= state[j]; |
|
} |
|
|
|
for (int i = 1; i < Nrow; i++) |
|
{ |
|
LD4S(state1, 2, i, thread, threads); |
|
LD4S(state2, rowInOut, i, thread, threads); |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= state1[j] + state2[j]; |
|
|
|
round_lyra(state); |
|
} |
|
|
|
#pragma unroll |
|
for (int j = 0; j < 3; j++) |
|
state[j] ^= last[j]; |
|
} |
|
|
|
__constant__ uint2x4 blake2b_IV[2] = { |
|
0xf3bcc908lu, 0x6a09e667lu, |
|
0x84caa73blu, 0xbb67ae85lu, |
|
0xfe94f82blu, 0x3c6ef372lu, |
|
0x5f1d36f1lu, 0xa54ff53alu, |
|
0xade682d1lu, 0x510e527flu, |
|
0x2b3e6c1flu, 0x9b05688clu, |
|
0xfb41bd6blu, 0x1f83d9ablu, |
|
0x137e2179lu, 0x5be0cd19lu |
|
}; |
|
|
|
__global__ __launch_bounds__(64, 1) |
|
void lyra2_gpu_hash_32_1(uint32_t threads, uint2 *g_hash) |
|
{ |
|
const uint32_t thread = (blockDim.x * blockIdx.x + threadIdx.x); |
|
if (thread < threads) |
|
{ |
|
uint2x4 state[4]; |
|
state[0].x = state[1].x = __ldg(&g_hash[thread + threads * 0]); |
|
state[0].y = state[1].y = __ldg(&g_hash[thread + threads * 1]); |
|
state[0].z = state[1].z = __ldg(&g_hash[thread + threads * 2]); |
|
state[0].w = state[1].w = __ldg(&g_hash[thread + threads * 3]); |
|
state[2] = blake2b_IV[0]; |
|
state[3] = blake2b_IV[1]; |
|
|
|
for (int i = 0; i<24; i++) |
|
round_lyra(state); //because 12 is not enough |
|
|
|
((uint2x4*)DMatrix)[threads * 0 + thread] = state[0]; |
|
((uint2x4*)DMatrix)[threads * 1 + thread] = state[1]; |
|
((uint2x4*)DMatrix)[threads * 2 + thread] = state[2]; |
|
((uint2x4*)DMatrix)[threads * 3 + thread] = state[3]; |
|
} |
|
} |
|
|
|
__global__ |
|
__launch_bounds__(TPB52, 1) |
|
void lyra2_gpu_hash_32_2(const uint32_t threads, uint64_t *g_hash) |
|
{ |
|
const uint32_t thread = blockDim.y * blockIdx.x + threadIdx.y; |
|
if (thread < threads) |
|
{ |
|
uint2 state[4]; |
|
state[0] = __ldg(&DMatrix[(0 * threads + thread) * blockDim.x + threadIdx.x]); |
|
state[1] = __ldg(&DMatrix[(1 * threads + thread) * blockDim.x + threadIdx.x]); |
|
state[2] = __ldg(&DMatrix[(2 * threads + thread) * blockDim.x + threadIdx.x]); |
|
state[3] = __ldg(&DMatrix[(3 * threads + thread) * blockDim.x + threadIdx.x]); |
|
|
|
reduceDuplex(state, thread, threads); |
|
reduceDuplexRowSetup(1, 0, 2, state, thread, threads); |
|
reduceDuplexRowSetup(2, 1, 3, state, thread, threads); |
|
reduceDuplexRowSetup(3, 0, 4, state, thread, threads); |
|
reduceDuplexRowSetup(4, 3, 5, state, thread, threads); |
|
reduceDuplexRowSetup(5, 2, 6, state, thread, threads); |
|
reduceDuplexRowSetup(6, 1, 7, state, thread, threads); |
|
|
|
uint32_t rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(7, rowa, 0, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(0, rowa, 3, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(3, rowa, 6, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(6, rowa, 1, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(1, rowa, 4, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(4, rowa, 7, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt(7, rowa, 2, state, thread, threads); |
|
rowa = WarpShuffle(state[0].x, 0, 4) & 7; |
|
reduceDuplexRowt_8(rowa, state, thread, threads); |
|
|
|
DMatrix[(0 * threads + thread) * blockDim.x + threadIdx.x] = state[0]; |
|
DMatrix[(1 * threads + thread) * blockDim.x + threadIdx.x] = state[1]; |
|
DMatrix[(2 * threads + thread) * blockDim.x + threadIdx.x] = state[2]; |
|
DMatrix[(3 * threads + thread) * blockDim.x + threadIdx.x] = state[3]; |
|
} |
|
} |
|
|
|
__global__ __launch_bounds__(64, 1) |
|
void lyra2_gpu_hash_32_3(uint32_t threads, uint2 *g_hash) |
|
{ |
|
const uint32_t thread = blockDim.x * blockIdx.x + threadIdx.x; |
|
if (thread < threads) |
|
{ |
|
uint2x4 state[4]; |
|
state[0] = __ldg4(&((uint2x4*)DMatrix)[threads * 0 + thread]); |
|
state[1] = __ldg4(&((uint2x4*)DMatrix)[threads * 1 + thread]); |
|
state[2] = __ldg4(&((uint2x4*)DMatrix)[threads * 2 + thread]); |
|
state[3] = __ldg4(&((uint2x4*)DMatrix)[threads * 3 + thread]); |
|
|
|
for (int i = 0; i < 12; i++) |
|
round_lyra(state); |
|
|
|
g_hash[thread + threads * 0] = state[0].x; |
|
g_hash[thread + threads * 1] = state[0].y; |
|
g_hash[thread + threads * 2] = state[0].z; |
|
g_hash[thread + threads * 3] = state[0].w; |
|
} |
|
} |
|
|
|
__global__ __launch_bounds__(64, 1) |
|
void lyra2_gpu_hash_64_1(uint32_t threads, uint2* const d_hash_512, const uint32_t round) |
|
{ |
|
const uint32_t thread = (blockDim.x * blockIdx.x + threadIdx.x); |
|
if (thread < threads) |
|
{ |
|
uint2x4 state[4]; |
|
const size_t offset = (size_t)8 * thread + (round * 4U); |
|
uint2 *psrc = (uint2*)(&d_hash_512[offset]); |
|
state[0].x = state[1].x = __ldg(&psrc[0]); |
|
state[0].y = state[1].y = __ldg(&psrc[1]); |
|
state[0].z = state[1].z = __ldg(&psrc[2]); |
|
state[0].w = state[1].w = __ldg(&psrc[3]); |
|
state[2] = blake2b_IV[0]; |
|
state[3] = blake2b_IV[1]; |
|
|
|
for (int i = 0; i<24; i++) |
|
round_lyra(state); |
|
|
|
((uint2x4*)DMatrix)[threads * 0 + thread] = state[0]; |
|
((uint2x4*)DMatrix)[threads * 1 + thread] = state[1]; |
|
((uint2x4*)DMatrix)[threads * 2 + thread] = state[2]; |
|
((uint2x4*)DMatrix)[threads * 3 + thread] = state[3]; |
|
} |
|
} |
|
|
|
__global__ __launch_bounds__(64, 1) |
|
void lyra2_gpu_hash_64_3(uint32_t threads, uint2 *d_hash_512, const uint32_t round) |
|
{ |
|
// This kernel outputs 2x 256-bits hashes in 512-bits chain offsets in 2 rounds |
|
const uint32_t thread = blockDim.x * blockIdx.x + threadIdx.x; |
|
if (thread < threads) |
|
{ |
|
uint2x4 state[4]; |
|
state[0] = __ldg4(&((uint2x4*)DMatrix)[threads * 0 + thread]); |
|
state[1] = __ldg4(&((uint2x4*)DMatrix)[threads * 1 + thread]); |
|
state[2] = __ldg4(&((uint2x4*)DMatrix)[threads * 2 + thread]); |
|
state[3] = __ldg4(&((uint2x4*)DMatrix)[threads * 3 + thread]); |
|
|
|
for (int i = 0; i < 12; i++) |
|
round_lyra(state); |
|
|
|
const size_t offset = (size_t)8 * thread + (round * 4U); |
|
uint2 *pdst = (uint2*)(&d_hash_512[offset]); |
|
pdst[0] = state[0].x; |
|
pdst[1] = state[0].y; |
|
pdst[2] = state[0].z; |
|
pdst[3] = state[0].w; |
|
} |
|
} |
|
#else |
|
#if __CUDA_ARCH__ < 500 |
|
|
|
/* for unsupported SM arch */ |
|
__device__ void* DMatrix; |
|
#endif |
|
__global__ void lyra2_gpu_hash_32_1(uint32_t threads, uint2 *g_hash) {} |
|
__global__ void lyra2_gpu_hash_32_2(uint32_t threads, uint64_t *g_hash) {} |
|
__global__ void lyra2_gpu_hash_32_3(uint32_t threads, uint2 *g_hash) {} |
|
__global__ void lyra2_gpu_hash_64_1(uint32_t threads, uint2* const d_hash_512, const uint32_t round) {} |
|
__global__ void lyra2_gpu_hash_64_3(uint32_t threads, uint2 *d_hash_512, const uint32_t round) {} |
|
#endif |
|
|
|
__host__ |
|
void lyra2_cpu_init(int thr_id, uint32_t threads, uint64_t *d_matrix) |
|
{ |
|
// just assign the device pointer allocated in main loop |
|
cudaMemcpyToSymbol(DMatrix, &d_matrix, sizeof(uint64_t*), 0, cudaMemcpyHostToDevice); |
|
} |
|
|
|
__host__ |
|
void lyra2_cpu_hash_32(int thr_id, uint32_t threads, uint64_t *d_hash, bool gtx750ti) |
|
{ |
|
int dev_id = device_map[thr_id % MAX_GPUS]; |
|
|
|
uint32_t tpb = TPB52; |
|
|
|
if (cuda_arch[dev_id] >= 520) tpb = TPB52; |
|
else if (cuda_arch[dev_id] >= 500) tpb = TPB50; |
|
else if (cuda_arch[dev_id] >= 200) tpb = TPB20; |
|
|
|
dim3 grid1((threads * 4 + tpb - 1) / tpb); |
|
dim3 block1(4, tpb >> 2); |
|
|
|
dim3 grid2((threads + 64 - 1) / 64); |
|
dim3 block2(64); |
|
|
|
dim3 grid3((threads + tpb - 1) / tpb); |
|
dim3 block3(tpb); |
|
|
|
if (cuda_arch[dev_id] >= 520) |
|
{ |
|
lyra2_gpu_hash_32_1 <<< grid2, block2 >>> (threads, (uint2*)d_hash); |
|
lyra2_gpu_hash_32_2 <<< grid1, block1, 24 * (8 - 0) * sizeof(uint2) * tpb >>> (threads, d_hash); |
|
lyra2_gpu_hash_32_3 <<< grid2, block2 >>> (threads, (uint2*)d_hash); |
|
} |
|
else if (cuda_arch[dev_id] >= 500) |
|
{ |
|
size_t shared_mem = 0; |
|
|
|
if (gtx750ti) |
|
// suitable amount to adjust for 8warp |
|
shared_mem = 8192; |
|
else |
|
// suitable amount to adjust for 10warp |
|
shared_mem = 6144; |
|
|
|
lyra2_gpu_hash_32_1_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash); |
|
lyra2_gpu_hash_32_2_sm5 <<< grid1, block1, shared_mem >>> (threads, (uint2*)d_hash); |
|
lyra2_gpu_hash_32_3_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash); |
|
} |
|
else |
|
lyra2_gpu_hash_32_sm2 <<< grid3, block3 >>> (threads, d_hash); |
|
} |
|
|
|
__host__ |
|
void lyra2_cuda_hash_64(int thr_id, const uint32_t threads, uint64_t* d_hash_256, uint32_t* d_hash_512, bool gtx750ti) |
|
{ |
|
int dev_id = device_map[thr_id % MAX_GPUS]; |
|
uint32_t tpb = TPB52; |
|
if (cuda_arch[dev_id] >= 520) tpb = TPB52; |
|
else if (cuda_arch[dev_id] >= 500) tpb = TPB50; |
|
else if (cuda_arch[dev_id] >= 200) tpb = TPB20; |
|
|
|
dim3 grid1((size_t(threads) * 4 + tpb - 1) / tpb); |
|
dim3 block1(4, tpb >> 2); |
|
|
|
dim3 grid2((threads + 64 - 1) / 64); |
|
dim3 block2(64); |
|
|
|
if (cuda_arch[dev_id] >= 520) |
|
{ |
|
const size_t shared_mem = sizeof(uint2) * tpb * 192; // 49152; |
|
lyra2_gpu_hash_64_1 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 0); |
|
lyra2_gpu_hash_32_2 <<< grid1, block1, shared_mem >>> (threads, d_hash_256); |
|
lyra2_gpu_hash_64_3 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 0); |
|
|
|
lyra2_gpu_hash_64_1 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 1); |
|
lyra2_gpu_hash_32_2 <<< grid1, block1, shared_mem >>> (threads, d_hash_256); |
|
lyra2_gpu_hash_64_3 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 1); |
|
} |
|
else if (cuda_arch[dev_id] >= 500) |
|
{ |
|
size_t shared_mem = gtx750ti ? 8192 : 6144; // 8 or 10 warps |
|
lyra2_gpu_hash_64_1_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 0); |
|
lyra2_gpu_hash_32_2_sm5 <<< grid1, block1, shared_mem >>> (threads, (uint2*)d_hash_256); |
|
lyra2_gpu_hash_64_3_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 0); |
|
|
|
lyra2_gpu_hash_64_1_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 1); |
|
lyra2_gpu_hash_32_2_sm5 <<< grid1, block1, shared_mem >>> (threads, (uint2*)d_hash_256); |
|
lyra2_gpu_hash_64_3_sm5 <<< grid2, block2 >>> (threads, (uint2*)d_hash_512, 1); |
|
} |
|
else { |
|
// alternative method for SM 3.x |
|
hash64_to_lyra32(thr_id, threads, d_hash_512, d_hash_256, 0); |
|
lyra2_cpu_hash_32(thr_id, threads, d_hash_256, gtx750ti); |
|
hash64_from_lyra32(thr_id, threads, d_hash_512, d_hash_256, 0); |
|
hash64_to_lyra32(thr_id, threads, d_hash_512, d_hash_256, 1); |
|
lyra2_cpu_hash_32(thr_id, threads, d_hash_256, gtx750ti); |
|
hash64_from_lyra32(thr_id, threads, d_hash_512, d_hash_256, 1); |
|
} |
|
}
|
|
|